gitout

A static git page generator
git clone https://git.bracken.jp/gitout.git
Log | Files | Refs | README | LICENSE

BUILD.gn (2019B)

      1 # TODO(cbracken): remove personal include, lib dirs.
      2 config("gitout_config") {
      3   include_dirs = [ "//" ] + system_include_dirs
      4   lib_dirs = [] + system_lib_dirs
      5   defines = [
      6     "_XOPEN_SOURCE=700",
      7     "_DEFAULT_SOURCE",
      8     "_BSD_SOURCE",
      9   ]
     10   libs = [ "git2" ]
     11   public_configs = [
     12     "//build:compiler_std",
     13     "//build:compiler_warnings",
     14     "//build:strict_prototypes",
     15   ]
     16   if (is_debug) {
     17     public_configs += [
     18       "//build:debug",
     19       "//build:no_optimize",
     20       "//build:symbols",
     21     ]
     22   } else {
     23     public_configs += [
     24       "//build:release",
     25       "//build:optimize_size",
     26       "//build:lto",
     27     ]
     28   }
     29 }
     30 
     31 group("default") {
     32   testonly = true
     33   deps = [
     34     ":gitout",
     35     ":gitout_index",
     36     ":gitout_tests",
     37   ]
     38 }
     39 executable("gitout") {
     40   sources = [ "gitout_main.c" ]
     41   configs += [ ":gitout_config" ]
     42   deps = [
     43     ":format",
     44     ":gitout_srcs",
     45     ":utils",
     46   ]
     47 }
     48 
     49 executable("gitout_index") {
     50   sources = [ "gitout_index_main.c" ]
     51   configs += [ ":gitout_config" ]
     52   deps = [ ":gitout_index_srcs" ]
     53 }
     54 
     55 executable("gitout_tests") {
     56   testonly = true
     57 
     58   sources = [
     59     "gitout_tests.c",
     60     "gitout_tests_main.c",
     61     "utils_tests.c",
     62   ]
     63   deps = [
     64     ":gitout_srcs",
     65     "//third_party/utest:utest_headers",
     66   ]
     67 }
     68 
     69 source_set("format") {
     70   sources = [
     71     "format.c",
     72     "format.h",
     73   ]
     74   configs += [ ":gitout_config" ]
     75 }
     76 
     77 source_set("gitout_index_srcs") {
     78   sources = [
     79     "gitout_index.c",
     80     "gitout_index.h",
     81   ]
     82   configs += [ ":gitout_config" ]
     83   deps = [
     84     ":security",
     85     "//git",
     86     "//writer:index_writer",
     87   ]
     88 }
     89 
     90 source_set("gitout_srcs") {
     91   sources = [
     92     "gitout.c",
     93     "gitout.h",
     94   ]
     95   configs += [ ":gitout_config" ]
     96   deps = [
     97     ":security",
     98     "//git",
     99     "//writer:repo_writer",
    100   ]
    101 }
    102 
    103 source_set("security") {
    104   sources = [
    105     "security.c",
    106     "security.h",
    107   ]
    108   configs += [ ":gitout_config" ]
    109 }
    110 
    111 source_set("utils") {
    112   sources = [
    113     "utils.c",
    114     "utils.h",
    115   ]
    116   configs += [ ":gitout_config" ]
    117   deps = [ "//third_party/openbsd" ]
    118 }